#
# Copyright (c) 1997-2001 Dirk Meyer
#

divert(0)dnl
VERSIONID(`@(#)demo.mc	$Revision: 1.5 $')

dnl ## Lokake Mailbox im passenden Format
OSTYPE(`bsd4.4')dnl
DOMAIN(`generic')dnl

dnl ## /etc/mail/sendmail.ct fuer TRUSTED user
FEATURE(`use_ct_file')dnl

dnl ## Mailertable fuer festes Routing zu Nachbarn
FEATURE(`mailertable', `hash -o /etc/mail/mailertable')dnl

dnl ## Virtusertable fuer freie Zuordung unserer Email-Adressen
FEATURE(`virtusertable', `hash -o /etc/mail/virtusertable')dnl

dnl ## Genricstable fuer lokaler Username zu Absender Email-Adresse.
FEATURE(`genericstable', `hash -o /etc/mail/genericstable')dnl

dnl ## Access-DB fuer Rechte von IP's und Domains
FEATURE(`access_db', `hash -o /etc/mail/access')dnl

dnl ## Keine DNS-Anfrage und Aenderung des Host-Namnes (CNAME)
FEATURE(`nocanonify')dnl

dnl ## es duerfen nur ganz wenige Programme ausgefuehert werden
FEATURE(`smrsh')dnl

FEATURE(`limited_masquerade')dnl

dnl ## den Neuen Mail-Service noch nicht verwenden
FEATURE(`no_default_msa')dnl

dnl ## Schwarze Listen erst pruefen, wenn wir wissen an wen
FEATURE(`delay_checks', `friends')dnl

dnl ## Risko: RELAY erlauben nur anhand des From-Headers
dnl FEATURE(`relay_mail_from', `domain')dnl

dnl ## Schwarze Listen:
FEATURE(dnsbl, `blackholes.mail-abuse.org', `Rejected $&{client_addr};- see  http://www.mail-abuse.org/rbl/')dnl
FEATURE(dnsbl, `relays.mail-abuse.org', `Open spam relay $&{client_addr}; - see http://www.mail-abuse.org/rss/')dnl
FEATURE(dnsbl, `dialups.mail-abuse.org', `Dialup $&{client_addr}; - see http://www.mail-abuse.org/dul/')dnl
FEATURE(dnsbl, `relays.orbs.org', `Open relay $&{client_addr}; see: http://www.orbs.org')dnl

dnl ## --------------------------------------------
dnl ## RELAYS

dnl ## Unbekannte Benutzer werden weitergeleitet an:
dnl define(`LUSER_RELAY',`postfach')dnl

dnl ## Falls erste Zustellung nicht klappt
dnl define(`confFALLBACK_MX', `mail.dinoex.sub.org')dnl

dnl ## --------------------------------------------
dnl ## Dateien und Pfade

dnl ## Aliases fuer Benutzer
dnl define(`ALIAS_FILE', `/etc/mail/aliases')dnl

dnl ## warte auf Aliases.db, und erzeuge sie selbst
define(`confCHECK_ALIASES', `True')dnl
define(`confAUTO_REBUILD', `True')dnl

dnl ## Hostnamen fuer das eigene System
define(`confCW_FILE', `-o /etc/mail/local-host-names')dnl

dnl ## es gibt Trusted USER z.B. uucp
define(`confTRUSTED_USERS' )
define(`confCT_FILE', `-o /etc/mail/trusted-users')dnl

dnl ## erkenne auch Rechner in /etc/hosts
define(`confHOSTS_FILE', `/etc/hosts')dnl

dnl ## durchsuche nicht netstat nach möglichen Rechnernamen
define(`confDONT_PROBE_INTERFACES', `True')dnl
define(`confDONT_INIT_GROUPS', `True')dnl

dnl ## --------------------------------------------
dnl ## Zustellung

dnl ## immer in die Queue zur Sicherheit
define(`confDELIVERY_MODE', `queued')dnl

dnl ## nach 4 mails in der Queue, default 10
define(`confCHECKPOINT_INTERVAL', `4')dnl

dnl ## 24 Hops treten bei Mailinglisten mit forwards schon mal auf
define(`confMAX_HOP', `24')dnl

dnl ## nach 1 Tag, Warnung an den Absender
define(`confTO_QUEUEWARN', `1d')dnl
define(`confTO_QUEUEWARN_NORMAL', `1d')dnl

dnl ## Maximal 7 Tage versuchen zuzustellen
define(`confTO_QUEUERETURN', `7d')dnl
define(`confMIN_QUEUE_AGE', `30m')dnl

dnl ## Timeouts lang wg. Teergruben
define(`confTO_RCPT', `10m')dnl
define(`confTO_DATABLOCK', `10m')dnl
define(`confTO_DATAFINAL', `10m')dnl
define(`confTO_COMMAND', `10m')dnl
define(`confMCI_CACHE_TIMEOUT', `10m')dnl

dbl ## mail.local ist nicht mehr suid
MODIFY_MAILER_FLAGS(`LOCAL', `+S')dnl

dnl ## --------------------------------------------
dnl ## Annahme ohne DNS
dnl define(`confBIND_OPTS',`-DNSRCH -DEFNAMES')

dnl ## wir koennen 8bit SMTP = ESMTP
define(`confSMTP_MAILER', `smtp8')dnl

dnl ## Ein einziges MB muß auf der Mail-Partion frei sein
define(`confMIN_FREE_BLOCKS', `1024')dnl

dnl ## maximal 120 Prozesse gleichzeitig
define(`confMAX_DAEMON_CHILDREN', `120')dnl
define(`confCONNECTION_RATE_THROTTLE', `3')dnl
define(`confSEPARATE_PROC', `True')dnl

dnl ## wast tun ohne To: Header ?
define(`confNO_RCPT_ACTION', `add-to-undisclosed')dnl

dnl ## VRFY aus, EXPN aus, ETRN aus
define(`confPRIVACY_FLAGS', ``authwarnings,novrfy,noexpn,noetrn,needmailhelo'')dnl

dnl ## eine Standard Received Zeile mit "envelope-from"
define(`confRECEIVED_HEADER', `$?sfrom $s $.$?_($?s$|from $.$_)
	$.$?{auth_type}(authenticated$?{auth_ssf} (${auth_ssf} bits)$.)
	$.by $j ($v/$Z)$?r with $r$. id $i$?{tls_version}
	(using ${tls_version} with cipher ${cipher} (${cipher_bits} bits) verified ${verify})$.$?u
	for $u$.; $b$?g
	(envelope-from $g)$.')

dnl ## --------------------------------------------
dnl ## Optionen

dnl ## Give Admin notice of errors
define(`confCOPY_ERRORS_TO', `Postmaster')dnl

dnl ## Include sender in group expansions
define(`confME_TOO', `True')dnl

dnl ## 10 MB per Mail ist Limit
define(`confMAX_MESSAGE_SIZE', `10000000')dnl

dnl ## --------------------------------------------
dnl ## Es geht los mit den Regeln

dnl ## der lokale Mailer kan LMTP und damit bessere Statusinformationen
FEATURE(`local_lmtp')dnl

MAILER(`local')dnl
MAILER(`smtp')dnl

dnl ## --------------------------------------------
dnl ## SPAM und mehr

LOCAL_CONFIG

dnl ## Diesen From Header wollen wir nicht sehen
Kchkfrm regex -a@REJ hahaha@sexyfun.net

LOCAL_RULESETS

dnl ## Automatich eine Empfangsbestaetigung anfordern
HReturn-Receipt-To: $?x$x <$g>$|$g$.

dnl ## Diese Headerzeile erzeugen wir extra
H?u?X-MDaemon-Deliver-To: $u

dnl ## Wir pruefen den Betreff
HSubject: $>CheckSubject

dnl ## Bestimmte Betreffzeilen werden nicht akzepiert
SCheckSubject
RILOVEYOU		$#error $: 553 ILOVEYOU Virus detected
RHere you have, ;o)	$#error $: 553 Anna Kournikova virus detected
RHere you are, ;o)	$#error $: 553 Anna Kournikova virus detected
RHere you go, ;o)	$#error $: 553 Anna Kournikova virus detected

dnl ## Wir pruefen den From-Header
HFrom: $>CheckFromHeader

dnl ## Bestimmte From-Header werden nicht akzepiert
SCheckFromHeader
R$*	$: $(chkfrm $1 $)
R@REJ	$#error $: 553 Some virus detected

dnl ## eof